SHIROのIchigoJam日記

マイコン「IchigoJam」（イチゴジャム）の電子工作とプログラミングをメインに

ドットイート10周年

IchigoJam

IchigoJamの10周年記念プログラム第2弾、ドットイートゲームです。

遊び方

  • 起動するとフロア画面が表示されて、自キャラの人間が右へ動き始めます。
  • 自キャラはキーを押さなくても前進し続けます。周囲の壁や文字に当たるとゲームオーバーなので、当たる前に上下左右の矢印キーで向きを変えてください。
  • フロア内のドットを全て消すとクリアです。なお、文字で囲まれた領域のドットは消さなくて良いです。
  • 全10面を全てクリアするとゲーム終了です。最後の3面「a」「m」「10」がなかなか大変です。頑張ってください。

プログラムリスト

10 '*DOT EAT 10
20 CLV:LET [0],1,0,0,1,-1,0,0,-1
30 LET [10],114,116,111,118,103,104,114,108,109,100
40 LET [28],2,0,3,1
50 VIDEO 3:P="IchigoJam*":POKE P+9,234
60 FOR F=0 TO 9
70 CLS:POKE #900,46:COPY #901,#900,175
80 FOR I=0 TO 16:?CHR$(1);:NEXT
90 FOR J=1 TO 8:LC 15,J:?CHR$(1,1);:NEXT
100 LC 15,9:FOR I=0 TO 16:?CHR$(1);:NEXT
110 LC 0,11:?"F=";F+1;
120 A=PEEK(P+F)*8
130 FOR B=0 TO 7
140 D=PEEK(A+B):M=128:LC 4,2+B
150 FOR I=0 TO 7
160 IF D&M ?CHR$(1); ELSE ?CHR$(46);
170 M=M>>1
180 NEXT
190 NEXT
200 X=1:Y=1:C=0:T=0:LC X,Y:?CHR$(249);
210 BEEP 10,30:WAIT 60
220 K=INKEY()
230 IF K C=[K]
240 LC X,Y:?" ";
250 X=X+[C*2]:Y=Y+[C*2+1]
260 R=SCR(X,Y):IF R=1 GOTO 330
270 IF R=46 S=S+1:T=T+1:LC 6,11:?"SC=";S;
280 LC X,Y:?CHR$(249);:WAIT 12
290 IF T<[10+F] GOTO 220
300 BEEP 10,30:WAIT 60
310 NEXT
320 LC 0,0:END
330 LC X,Y:?"X";
340 BEEP 30,30:WAIT 60
350 LC 0,0:END

280行の「WAIT 12」が自キャラが動く時の時間待ちです。どうしてもクリアできなかったらこのWAITを変えてください。

IchigoJam web版

IchigoJam web版はこちら。WAITを調整しています。

かわくだり10周年

IchigoJam

fukuno.jig.jp

IchigoJamは2014年4月1日に試作版が発表されてから、今年で10周年です。おめでとうございます＼(^_^)／
10周年を記念して、IchigoJam入門プログラムとして有名な「かわくだりゲーム」の10周年記念版を作ってみました。


プレイ画面です。通常のかわくだりとほぼ同じ画面ですが、自分のキャラが「I」になっています。
下から流れてくる岩を避けつつ、時々「c」が流れてくるので、それを取りに行ってください。
「c」を取ると自キャラが「Ic」に伸びて、次は「h」が流れてきます。その調子で自キャラを1文字ずつ伸ばしていってください。


全ての文字で当たり判定があるので、自キャラが伸びるほど岩を避けるのが難しくなります。


「IchigoJam10」の10文字まで伸ばせたら人間の勝ちですが、なかなかそこまで行けないでしょう。

プログラム

10 P="IchigoJam*":POKE P+9,234
20 CLS:CLT:X=16:L=1
30 X=X-BTN(28)+BTN(29)
40 X=X&31
50 FOR N=0 TO L-1
60 C=SCR((X+N)&31,5+(X+N>31))
70 IF C=PEEK(P+L) L=L+(L<10):C=0
80 IF C ?TICK()/60:END
90 NEXT
100 LC X,5:?STR$(P,L)
110 LC RND(32),23
120 IF RND(10) ?"*" ELSE ?STR$(P+L,1)
130 WAIT 3
140 GOTO 30

自キャラの全ての文字で当たり判定をしているので、自キャラが伸びるほど川の流れが遅くなります。それでも私は「Ichigo」くらいまでしか伸ばせません(^_^;)
あまりに難しいようなら、130行の「WAIT 3」のウェイトを増やして、流れを遅くしてみてください。

IchigoJam web版

IchigoJam web版はこちら。時間待ちを「WAIT 0」にしていますが、かなり遅いです。