SHIROのIchigoJam日記

IchigoJamの電子工作とプログラミングをメインに

IchigoJamスポーツ

IchigoJamの入門テキスト「はじめのいっぽ/ミニゲームズ」の次のステップのペーパーとして、「IchigoJamスポーツ」を作ってみました。
スポーツを題材にしたミニプログラム4本です。
このペーパーとプログラムは、CC BYライセンスとします。ご自由にお使いください。

100mダッシュ


1 '*100m Dash* CC BY Copyright (c) 2017 Shiro SAITO
10 ?CHR$(251);:CLT
20 FOR R=1 TO 100
30 IF !BTN(32) CONT
40 IF BTN(32) CONT
50 ?CHR$(8,46,251);
60 NEXT
70 BEEP:T=TICK()
80 ?:?T/60;".";T%60/6

走りはばとび


1 '*Long Jump* CC BY Copyright (c) 2017 Shiro SAITO
10 CLS:CLV:LC 0,23:FOR X=0 TO 30:?CHR$(1);:NEXT
20 X=0:Y=22:LC X,Y:?CHR$(251):CLT
30 IF !SCR(0,23) BEEP 30,60:END
40 K=INKEY():IF K=29 LC 0,Y:?CHR$(0,251):SCROLL 3:V=V+10/TICK():CLT
50 IF K<>32 GOTO 30
60 BEEP:E=-6
70 LC X/20,Y:?" ":X=X+V:Y=Y+E:E=E+1
80 LC X/20,Y:?CHR$(251):WAIT 5
90 IF Y<22 GOTO 70
100 LC 0,0:?X/20;"m"

PKせん


1 '*PK* CC BY Copyright (c) 2017 Shiro SAITO
10 CLV
20 CLS:?"[=====";CHR$(250);"=====]"
30 X=6:LC X,6:?CHR$(233)
40 LC 0,9:?"GOAL=";G
50 D=BTN(29)-BTN(28)
60 IF !D GOTO 50
70 FOR Y=6 TO 2 STEP -1
80 LC X,Y:?" ":X=X+D
90 LC X,Y-1:?CHR$(233):WAIT 5
100 NEXT
110 LC 6,0:?"="
120 R=RND(2)*2-1
130 LC 6+R*5,0:?CHR$(252-R)
140 IF D<>R G=G+1:BEEP 10,3:WAIT 100:GOTO 20
150 BEEP 30,60:LC 0,10

かべうちテニス


1 '*Wall Tennis* CC BY Copyright (c) 2017 Shiro SAITO
10 CLS:CLV:FOR X=0 TO 31:?"=";:NEXT
20 FOR Y=1 TO 21:LC 0,Y:?"|":LC 31,Y:?"|":NEXT
30 P=RND(27):LC P,22:?"=====";
40 X=P+1:Y=21:LC X,Y:?CHR$(233):D=-1:E=-1
50 U=X+D:V=Y+E:C=SCR(U,V)
60 IF C=124 BEEP 20,3:D=-D:GOTO 50
70 IF C=61 BEEP 10,3:E=-E:S=S+1:GOTO 50
80 LC X,Y:?" ";:LC U,V:?CHR$(233);:X=U:Y=V
90 Q=P-BTN(28)*(P>0)+BTN(29)*(P<27)
100 LC P,22:?" ";:LC Q,22:?"=====";:P=Q
110 WAIT 3:IF V<22 GOTO 50
120 BEEP 30,60:LC 15,11:?S

変更履歴

2015/11/12
  • 「走りはばとび」のプログラムを変更
2015/11/15
  • 「かべうちテニス」で、スクロールバグの回避方法がわかったので、フィールドの横幅を画面一杯に変更。
  • ファームウェアでボールの動きが速くなったので、パドルの幅を1文字分増やしました。それでも「かわくだりゲーム」並に難しいです(笑)
2016/7/30
  • 100mダッシュ
    • FOR〜NEXTを使ってプログラムを短くしました。
  • 走りはばとび
    • 1文字だけプログラムを短くしました。
  • PKせん
    • キー入力読み取り部分を改善して、プログラムを短くしました。
  • かべうちテニス
    • ゲームがあまりに難しいので、ラケットを大きくする、WAITを入れて動きを遅くするなどして、やさしくしました。
2017/7/1
  • 100mダッシュ
    • スペースキーを連打する操作に変えて、プログラムを短くしました。「かわくだりゲーム」並みに短いプログラムになったので、プログラム体験教室などでもいかがでしょうか。
2017/7/10
  • 走りはばとび
    • 初期設定を若干変更しました。
  • PKせん、かべうちテニス
    • キースキャン部を変更して、プログラムを若干短縮しました。