SHIROのIchigoJam日記

IchigoJamの電子工作とプログラミングをメインに

IchigoLatte正式版/2進数&16進数学習機「Ichigo216」

発売になったIchigoLatte正式版を購入して、さっそく工作してみました。

パッケージは箱形です。


基板の表面。IC・抵抗・コンデンサーなどのチップ部品はあらかじめ実装されています。
ICの上下に2つの「Latteキャンパス」があって、簡単な回路が作り込めるようになっています。


基板の裏面。2つのLatteキャンパスの間に+5V、GND、+3.3Vのパターンが引き出されています。回路作りに便利。


というわけでハンダ付け。上記のようにチップ部品はあらかじめ実装されているので、ハンダ付けする部品は少ないです。ほどなく完成。

さっそくLatteキャンパスを活かした工作を開始。
FacebookのIchigoJam-FANグループで、7セグメントLEDを載せて16進数を表示していた方がいたので、それを応用して、2進数&16進数学習機「Ichigo216」(イチゴにじゅうろく)を作りました。

上のキャンパスは4個の角形LEDで2進数表示(OUT8〜11で制御)、下のキャンパスは小型7セグメントLEDで16進数を表示します(OUT1〜7で制御)。

基板の裏側の配線はえらいことになっています(^_^;)

回路図はこちら。OUT10(IN3)端子だけプルアップが必要なのでプルアップ抵抗を付けています。

プレイ動画はこちら。

プログラムはこちら。ファームウェアIchigoJamに書きかえて、BASICで作っています。

  • プログラムを起動すると、選択メニューになります。ボタンを1回押すとモード1、2回押すとモード2を選択します。
  • モード1はカウンターです。最初は「0」が表示されます。ボタンを押すと1ずつカウントアップします。15(2進数で「●●●●」、16進数で「F」)まで行くと、次は0に戻ります。
  • モード2はルーレットです。最初は「0」が表示されます。ボタンを押すとルーレットが高速に回ります。もう1回押すとゆっくりになって止まります。再度ボタンを押すとくり返し回せます。
  • そのまま選択メニューに戻らないので、戻るにはプログラムを再起動してください。

10 '*Ichigo216
20 CLV:CLO:SRND(ANA(2))
30 FOR P=1 TO 11:OUT P,0:NEXT
40 LET [0],`0111111,`0000110,`1011011,`1001111,`1100110,`1101101,`1111101,`0100111
50 LET [8],`1111111,`1101111,`1110111,`1111100,`0111001,`1011110,`1111001,`1110001
60 IF BTN() CONT
70 GSB 540
80 BEEP 30,60
90 IF !BTN() CONT
100 GSB 180
110 '@SLOOP
120 IF BTN() GSB 180
130 IF TICK()<60 GOTO 110
140 BEEP 10,2:WAIT 8:BEEP 10,2
150 WAIT 60
160 IF N=1 GOTO 240
170 IF N=2 GOTO 340
180 '@INPUT1
190 N=N+1:IF N>2 N=1
200 GSB 520
210 IF BTN() CONT
220 CLT:RTN
230 '
240 '@COUNTER
250 N=0:GSB 540
260 '@CLOOP
270 IF !BTN() CONT
280 N=N+1
290 IF N>15 N=0
300 GSB 520
310 WAIT 30
320 GOTO 260
330 '
340 '@ROULETTE
350 N=0:GSB 540
360 '@RLOOP
370 IF !BTN() CONT
380 IF BTN() CONT
390 '@RLOOP1
400 N=RND(16)
410 GSB 520
420 WAIT 5
430 IF !BTN() GOTO 390
440 FOR I=1 TO 5
450 N=RND(16)
460 GSB 520
470 WAIT 15
480 NEXT
490 WAIT 30
500 GOTO 360
510 '
520 '@PRTN
530 BEEP 10,2
540 '@PRTN1
550 OUT N*128+[N]
560 RTN