SHIROのIchigoJam日記

IchigoJamの電子工作とプログラミングをメインに

PK戦ボードV2

以前作ったPK戦ボードが、意外に子どもに分かりづらく不評だったので、改良したVer.2を作りました。
左右ボタンの追加、ボールコースのLEDを追加するなどしました。
プレイ動画はこちら。


遊び方

  • プログラムを起動すると、左右のボールコースが点滅します。
  • 蹴る方向を左右ボタンで選んでシュートします。GKの逆を突くとゴールゲットで、下のゲージが1点増えます。4点を越えると0点表示に戻りますが、なかなかそこまで行かないでしょう。
  • GKに止められるとゲームオーバーです。左ボタンを押すとリプレイします。

基板データ

*この基板ガーバーデータは、CC BYライセンスとします。どうぞご利用ください。

(C) 2018 Shiro Saito (http://d.hatena.ne.jp/shiro0922/)

このファイルをそのままFusion PCBで登録すれば、基板を発注できます。
基板寸法は60×36mmです。

プログラムリスト

「子どもにわかりやすく」と考えて、冗長なプログラムになっています。

10 '*PK
20 CLV
30 OUT 0
40 IF BTN()=1 THEN CONT
50 '@START
60 FOR I=5 TO 10
70 OUT I,0
80 NEXT
90 WAIT 30
100 D=0
110 '@INBTN
120 OUT 5+D,1
130 OUT 7+D,1
140 WAIT 2
150 OUT 5+D,0
160 OUT 7+D,0
170 WAIT 1
180 IF BTN()=1 THEN D=0:GOTO 220
190 IF IN(4)=0 THEN D=1:GOTO 220
200 D=1-D
210 GOTO 110
220 '@SHOOT
230 BEEP
240 WAIT 30
250 OUT 5+D,1
260 WAIT 10
270 OUT 7+D,1
280 WAIT 10
290 SRND ANA(2)+TICK()
300 R=RND(2)
310 OUT 9+R,1
320 WAIT 30
330 IF D=R THEN GOTO 420
340 BEEP 10,30
350 G=G+1
360 IF G>4 THEN G=0
370 FOR I=1 TO 4
380 IF I<=G THEN OUT I,1 ELSE OUT I,0
390 NEXT
400 WAIT 60
410 GOTO 50
420 '@END
430 BEEP 30,60
440 WAIT 60
450 IF BTN()=0 THEN CONT
460 RUN