LEDボタン基板

LED内蔵のタクトスイッチを4個並べた、IchigoJam用拡張基板です。
もぐらたたきやサイモン（記憶ゲーム）など、アイデア次第でいろいろ遊べます。
紹介動画はこちら。

www.youtube.com

回路図

4個のLED内蔵タクトスイッチ（ボタン）を各ポートにつないでいます。つなぎ方は以下のとおりです。

	LED点灯	ボタン入力
ボタン3	OUT3	IN3
ボタン4	OUT4	IN4
ボタン5	OUT5	IN5(OUT1)
ボタン6	OUT6	IN6(OUT2)

入力も出力もポート3～6と揃えて、わかりやすくしています(^_^)
なお、ボタン入力はプルアップで使います。
（押されていない＝入力値が「1」、押された＝入力値が「0」）
プログラムの初期設定で、各ポートをプルアップにしておいてください。

OUT 10,-2:OUT 11,-2:OUT 1,-2:OUT 2,-2

基板データ

• Fusion PCB用ガーバーデータ（ZIP）（98×69mm）

＊同じ基板を3枚並べて配置しています。
＊この基板データは、CC BYライセンスとします。どうぞご利用ください。

(C) 2025 Shiro Saito (https://www.ichigoaman.jp)

材料

だいたい以下の順番ではんだ付けすると作りやすいです。

• カーボン抵抗(炭素皮膜抵抗) 1/4W2.4kΩ　R1
• カーボン抵抗(炭素皮膜抵抗) 1/4W100Ω　R3,R4
• カーボン抵抗(炭素皮膜抵抗) 1/4W330Ω　R5,R6
• ★12x12★LED付きタクトスイッチ ATD-12X12LED （aitendo）　×4個
  • 青（ボタン3）、緑（ボタン4）、黄（ボタン5）、赤（ボタン6）の4色を使って下さい。電流制限抵抗（R3～R6）をそれに合わせてあります。
• ピンヘッダー 1×40 (40P)　※14ピン×2本にカット

プログラム

テストプログラム

ボタン3，4，5，6の順番にLEDが点灯するので、ボタンを押して次に進んでください。

10 CLV:OUT 0
20 OUT 10,-2:OUT 11,-2:OUT 1,-2:OUT 2,-2
100 FOR P=3 TO 6
110 OUT P,1
120 IF IN(P) CONT
130 OUT P,0
140 NEXT

もぐらたたき

テストプログラムを改造して作ります。
LEDが光ったボタンを押してください。もぐらの動きがだんだん速くなり、押すのが間に合わないとゲームオーバーです。

10 CLV:OUT 0
20 OUT 10,-2:OUT 11,-2:OUT 1,-2:OUT 2,-2
30 W=62:WAIT 60
100 P=RND(4)+3:W=W-2
110 OUT P,1
115 CLT
120 IF IN(P) CONT
130 OUT P,0
140 IF TICK()<W BEEP:S=S+1:?S:GOTO 100
150 BEEP 30,30

サイモン（記憶ゲーム）

起動すると、LEDのどれかがランダムに光ります。そのボタンを押します。
次は出題が1個増えて、LEDが2個光ります。そのとおりに押します。
出題が1個ずつ増えていくので、正確にその順番で押してください。間違えるとゲームオーバーです。

10 '*SIMON
20 CLV:SRND TICK():OUT 0
30 OUT 10,-2:OUT 11,-2:OUT 1,-2:OUT 2,-2
40 LET [93],"C","E","G","<C"
50 WAIT 60
60 @QUEST
70 M=M+1:?M
80 [M]=RND(4)+3
90 FOR I=1 TO M
100 N=[I]
110 OUT N,1
120 PLAY [90+N]:WAIT 30
130 OUT N,0
140 NEXT
150 A=0
160 @ALOOP
170 N=0
180 FOR P=3 TO 6
190 IF IN(P)=0 N=P
200 NEXT
210 IF N=0 GOTO @ALOOP
220 A=A+1
230 IF N!=[A] OUT 60:BEEP 30,60:END
240 OUT N,1
250 PLAY [90+N]:WAIT 30
260 OUT N,0
270 IF A<M GOTO @ALOOP
280 WAIT 60
290 GOTO @QUEST