GIGA IchigoDakeのシリアルコンソールで遊べるプログラムとして、三択の選択肢を選んで進むゲームエンジンを作ってみました。
もちろん通常のIchigoJam/IchigoDakeやIchigoJam webでも遊べます。
サンプルプログラムとして「IchigoJamクイズ」と「RPG」を作ってみました。
出題データを変えればいろいろなコンテンツが作れますので、皆さんもぜひ(^_^)
IchigoJamクイズ
IchigoJamについてのクイズが3問出題されます。正解すると点数が増えます。
10 '*3TAKU
20 CLV:CLS:Q=1
30 S=S*(Q>1):GSB 1000+Q
40 ?"@";Q;".";STR$([0])
50 FOR N=1 TO 3
60 ?"(";N;")";STR$([N*2-1])
70 NEXT
80 ?"ﾄﾞﾚ?":INPUT "",A:IF A<1 OR A>3 CONT
90 D=[A*2]
100 IF D=-2 END
110 IF D=-1 S=S+1:?"ｾｲｶｲ! ";S;"ﾃﾝ"
120 IF D>0 Q=D ELSE Q=Q+1
130 ?:GOTO 30
1001 LET[0],"IchigoJamﾉ ﾌﾙｻﾄﾊ?","ﾌｸｲｹﾝ",-1,"ﾄｳｷｮｳﾄ",0,"ﾅｶﾞﾉｹﾝ",0:RTN
1002 LET[0],"IchigoJamﾉ ﾅﾏｴﾉ ﾕﾗｲﾊ?","ｱﾏｸﾃ ｵｲｼｲｶﾗ",0,"ｲﾁｺﾞｶﾞ ｽｷﾀﾞｶﾗ",0,"ﾈﾀﾞﾝｶﾞ $15ﾀﾞｶﾗ",-1:RTN
1003 LET[0],"IchigoJamﾉ ﾀﾝｼﾞｮｳﾋﾞﾊ?","1/15",0,"4/1",-1,"11/15",0:RTN
1004 LET[0],"ｸｲｽﾞｼｭｳﾘｮｳ","ｻｲﾁｮｳｾﾝ",1,"ｵﾜﾙ",-2,"ｵﾜﾙ",-2:RTN★IchigoJam web動物シェア＝ヤク、アイアイ、ミンク
10～130行が共通ゲームエンジン、1001行～が出題データです。
出題データの形式は以下のとおりです。各行で配列変数[0]～[6]に出題データを設定してRETURNします。
- [0]＝問題文
- [1]＝選択肢1（文字列）
- [2]＝選択肢1の飛び先問題No.
- 選んだ時の飛び先の問題番号を指定します。クイズの場合は正解は「-1」・間違いは「0」で、正解すると得点をカウントします。「-2」はプログラムを終了します。
- [3]＝選択肢2（文字列）
- [4]＝選択肢2の飛び先問題No.
- [5]＝選択肢3（文字列）
- [6]＝選択肢3の飛び先問題No.
RPG
10 '*3TAKU
20 CLV:CLS:Q=1
30 S=S*(Q>1):GSB 1000+Q
40 ?"@";Q;".";STR$([0])
50 FOR N=1 TO 3
60 ?"(";N;")";STR$([N*2-1])
70 NEXT
80 ?"ﾄﾞﾚ?":INPUT "",A:IF A<1 OR A>3 CONT
90 D=[A*2]
100 IF D=-2 END
110 IF D=-1 S=S+1:?"ｾｲｶｲ! ";S;"ﾃﾝ"
120 IF D>0 Q=D ELSE Q=Q+1
130 ?:GOTO 30
1001 LET[0],"[ｵｼﾛ]ﾕｳｼｬﾖ. ﾎﾞｳｹﾝﾆ ｲｯﾃｸﾚﾙｶ?","ｲｸ",2,"ｺﾄﾜﾙ",1,"ｲｴﾆ ﾋｷｺﾓﾙ",99:RTN
1002 LET[0],"[ﾏﾁ]ﾄﾞｺﾍ ｲｸ?","ﾌﾞｷﾔ",3,"ｵｼﾛ",1,"ｿﾄﾍ ﾃﾞﾙ",4:RTN
1003 LET[0],"[ﾌﾞｷﾔ]ﾅﾆｦ ｶｳ?","ﾕｳｼｬﾉ ﾂﾙｷﾞ",4,"ﾕｳｼｬﾉ ﾖﾛｲ",4,"ｳﾏｲ ｻｹ",99:RTN
1004 LET[0],"[ﾜｶﾚﾐﾁ]ﾄﾞﾁﾗﾍ ｲｸ?","ﾐｷﾞ",10,"ﾋﾀﾞﾘ",5,"ﾏﾁﾍ ﾓﾄﾞﾙ",2:RTN
1005 LET[0],"[ｲｷﾄﾞﾏﾘ]ﾓﾄﾞﾙ?","ﾜｶﾚﾐﾁﾍ",4,"ﾏﾁﾍ",2,"ｵｼﾛﾍ",1:RTN
1010 LET[0],"ﾓﾝｽﾀｰｶﾞ ｱﾗﾜﾚﾀ!","ｺｳｹﾞｷ",11,"ﾏﾎｳ",12,"ﾆｹﾞﾙ",99:RTN
1011 LET[0],"ﾓﾝｽﾀｰﾆ ﾀﾞﾒｰｼﾞ!","ｺｳｹﾞｷ",11,"ﾏﾎｳ",12,"ﾆｹﾞﾙ",99:RTN
1012 LET[0],"ﾓﾝｽﾀｰｦ ﾀｵｼﾀ!","ｵｼﾛﾍ",100,"ﾏﾁﾍ",2,"ｵﾜﾙ",-2:RTN
1099 LET[0],"[ｵｼﾛ]ｵｵ,ﾕｳｼｬﾖ! ﾅﾝﾄｲｳｺﾄｼﾞｬ!","ｵﾕﾙｼｦ",99,"ｻｲﾁｮｳｾﾝ",1,"ｵﾜﾙ",-2:RTN
1100 LET[0],"[ｵｼﾛ]ｵｵ,ﾕｳｼｬﾖ! ｱﾘｶﾞﾄｳ!","ﾄﾞｳｲﾀｼﾏｼﾃ",100,"ﾓｳｲﾁﾄﾞ",1,"ｵﾜﾙ",-2:RTN★IchigoJam web動物シェア＝スカンク、カバ、ヤマアラシ
選択肢を選んで冒険の旅へ出てください。おかしな選択肢を選ぶと王様に怒られます(^_^)
出題データで飛び先をあちこちの問題にすることで、いろいろなストーリー展開が作れます。
※注意ですが、GIGA IchigoDakeのシリアルコンソール（DirectApps）だと、カタカナの入力やペーストができません。通常のIchigoJam/IchigoDake環境では問題ありません。
