SHIROのIchigoJam日記

マイコン「IchigoJam」（イチゴジャム）の電子工作とプログラミングをメインに

LEDセンサー基板2023

IchigoJam 電子工作

以前作ったLEDセンサー基板の簡略化バージョンです。
LED×8個と光センサー（フォトトランジスタ）が載っています。
IchigoJamやIchigoDakeに差して使えます。

回路図


8本のLEDはOUT1～8に、フォトトランジスタはIN2（ANA2）につながっています。
抵抗内蔵LEDを使用、ブザーを省略するなどして、部品点数を減らしました。

基板データ

＊同じ基板を6枚割り付けしています。
＊この基板データは、CC BYライセンスとします。どうぞご利用ください。

(C) 2023 Shiro Saito (https://www.ichigoaman.jp)

材料

以下の順番ではんだ付けすると作りやすいです。

プログラム

照度計

起動すると8個のLEDが光ります。光センサーを指で暗くすると、LEDの光がメーターのような動きをします。

10 A=ANA(2)
20 FOR P=1 TO 8
30 OUT P,A>P*100
40 NEXT
50 GOTO 10

ルーレット

起動すると8個のLEDがランダムに光って止まります。スペースキーを押すともう一度回ります。

10 FOR A=1 TO 10
20 OUT 0
30 BEEP 10,2
40 P=RND(8)+1
50 OUT P,1
60 WAIT 6
70 NEXT
80 IF !BTN(32) CONT
90 GOTO 10

バーサライタ（POV）

起動すると8個のLEDが点滅します。基板全体を左右に振るとハート形が見えます。
IchigoDyhook＋IchigoDake環境なら、IchigoDyhookごと持って左右に振るといいです。

10 CLV:OUT 8,0
100 [0]=`01110000
110 [1]=`11111000
120 [2]=`11111100
130 [3]=`01111110
140 [4]=`00111111
150 [5]=`01111110
160 [6]=`11111100
170 [7]=`11111000
180 [8]=`01110000
190 FOR L=0 TO 9
200 OUT [L]
210 WAIT -50
220 NEXT
230 GOTO 190
  • 210行のWAITはIchigoJam RやGIGA IchigoDake用です。IchigoJam SやIchigoDakeでは210行は入力しないでください。
  • 100～180行のパターンを変えると見える文字が変わります（1＝点灯、0＝消灯）。ハートのように左右対称の文字にすると見やすいです。

★祝！IchigoJam９周年★

IchigoJam

2023年4月1日はIchigoJam９周年の日です。
ちょっと思いついて歌動画を作ってみました。

www.youtube.com

なお「線路は続くよどこまでも」の歌は、メロディはアメリカ民謡なので著作権はありません。
日本語の歌詞は著作権がありますが、それの改変ではなく、全くオリジナルの作詞なら問題無いようです。

「みんなのIchigoJam」

てのひらパソコン IchigoJam
プログラミングを やってみよう
電子工作も 楽しいよ
みんなで作ろう IchigoJam

打って 打って RUN
打って 打って RUN
打って 打って RUN RUN RUN RUN RUN
打って 打って RUN
打って 打って RUN
打って 打って RUN RUN RUN

「打って打ってRUN」には、「論よりRUN」、とにかく作って動かしてみよう！という気持ちを込めています。「作ってみた」は正義！

ボーカル


「VOCALOID」を初めて触りましたが、なかなか楽しかったです(^_^)
もっと明るく跳ねる歌い方にしたかったのですが、難しかったです。調教法を勉強しないといけませんね。

伴奏


自分では作曲できないので、自動伴奏ツール「ChordPulse」を使ってみました。
コード進行と伴奏スタイルを指定すると、自動で伴奏を作ってくれます。
標準MIDIファイル（*.mid）を出力するので、別ツールでWAVに変換。

ビデオ編集


動画作成にいつも使っている「TMPGEnc Video Mastering Works」で、画像素材と音素材を組み合わせて編集しました。

グラディウスフォント

IchigoJam


ちょっと思いつきで、昔のゲーム「グラディウス」のフォントっぽいものを、IchigoJamのPCGで作ってみました。な、懐かしい…(^_^)

プログラム

PCG設定プログラムと文字列表示プログラムの2ファイルです。
ファイル0とファイル1にSAVEして、「LRUN0」でファイル0から実行してください。
連続した番号のファイルであれば、0番・1番でなくても構いません。

ファイル0「PCG設定」

文字コード224からアルファベットA～Zの26文字を設定します。

10 'GRADIUS FONT SET
20 POKE#700,2,6,10,18,#3E,#42,#82,0,#F8,#84,#82,#FC,#84,#82,#FC,0
30 POKE#710,#FE,#80,#80,#80,#80,#80,#FE,0,#F0,#88,#84,#82,#84,#88,#F0,0
40 POKE#720,#FE,#80,#80,#FC,#80,#80,#FE,0,#FE,#80,#80,#FC,#80,#80,#80,0
50 POKE#730,#FE,#80,#80,#9E,#82,#82,#FE,0,#82,#82,#82,#FE,#82,#82,#82,0
60 POKE#740,16,16,16,16,16,16,16,0,#FE,8,8,8,8,8,#F8,0
70 POKE#750,#82,#84,#88,#90,#88,#84,#82,0,#80,#80,#80,#80,#80,#80,#FE,0
80 POKE#760,#82,#C6,#AA,#92,#82,#82,#82,0,#82,#C2,#A2,#92,#8A,#86,#82,0
90 POKE#770,#FE,#82,#82,#82,#82,#82,#FE,0,#FE,#82,#82,#9E,#80,#80,#80,0
100 POKE#780,#FE,#82,#82,#82,#92,#8A,#FA,0,#FE,#82,#82,#9E,#88,#84,#82,0
110 POKE#790,#FE,#80,#80,#FE,2,2,#FE,0,#FE,16,16,16,16,16,16,0
120 POKE#7A0,#82,#82,#82,#82,#82,#82,#FE,0,#82,#84,#88,#90,#A0,#C0,#80,0
130 POKE#7B0,#89,#99,#AA,#AA,#CC,#CC,#88,0,#82,#44,#28,16,#28,#44,#82,0
140 POKE#7C0,#82,#44,#28,16,16,16,16,0,#FE,4,8,16,32,64,#FE,0
150 LRUNFILE()+1

ファイル1「文字列表示」

10 'GRADIUS FONT VIEW
20 VIDEO 3:CLS
30 S="ICHIGOJAM":GSB 100
40 S="GRADIUS FONT":GSB 100
50 ?
60 S="ABCDEFGHIJKLMNOPQRSTUVWXYZ":GSB 100
70 ?:END
100 L=LEN(S)-1
110 FOR A=S TO S+L
120 D=PEEK(A)+159
130 IF D=191 D=32
140 ?CHR$(D);
150 NEXT:?
160 RTN