SHIROのIchigoJam日記

マイコン「IchigoJam」(イチゴジャム)の電子工作とプログラミングをメインに

ビンゴゲーム

IchigoJamで数字を扱うプログラムとして、おなじみのビンゴゲームを作ってみました。
何かキーを押すと、1〜75の数字をランダムに出します。
配列を使って、一度出た数字は出ないように処理しています。
これまで出た数字が画面に一覧表示されるので、答え合わせもできます。
子ども達のプログラム学習教材として使うことを想定して、単純(冗長)なプログラムになっています。

10 '*BINGO*
20 CLV:CLS
30 GOSUB 290
40 '
50 '@SHOOT
60 LOCATE 0,20
70 PRINT "PUSH KEY"
80 '@SHOOT1
90 IF INKEY()=0 GOTO 80
100 '
110 FOR I=1 TO 20
120 '@SHOOTR
130 S=RND(75)+1
140 IF [S]=1 GOTO 120
150 LOCATE 0,20
160 PRINT "SHOOTING...";S;" ";
170 NEXT
180 C=C+1
190 [S]=1
200 GOSUB 290
210 '
220 '@SHOOT2
230 IF INKEY()=0 GOTO 220
240 LOCATE 0,20
250 PRINT " "
260 IF C<75 GOTO 50
270 END
280 '
290 '@NLIST
300 LOCATE 0,0
310 PRINT "B= ";
320 FOR N=1 TO 15
330 IF [N]=0 THEN PRINT "--."; ELSE IF N<10 THEN PRINT " ";N;"."; ELSE PRINT N;".";
340 NEXT
350 LOCATE 0,3
360 PRINT "I= ";
370 FOR N=16 TO 30
380 IF [N]=0 THEN PRINT "--."; ELSE PRINT N;".";
390 NEXT
400 LOCATE 0,6
410 PRINT "N= ";
420 FOR N=31 TO 45
430 IF [N]=0 THEN PRINT "--."; ELSE PRINT N;".";
440 NEXT
450 LOCATE 0,9
460 PRINT "G= ";
470 FOR N=46 TO 60
480 IF [N]=0 THEN PRINT "--."; ELSE PRINT N;".";
490 NEXT
500 LOCATE 0,12
510 PRINT "O= ";
520 FOR N=61 TO 75
530 IF [N]=0 THEN PRINT "--."; ELSE PRINT N;".";
540 NEXT
550 RETURN